{----------------------------------------------------------------------

インタプリタ

* LetRec +
* エラーメッセージの導入

 Expr -> Expr || Expr | Expr && Expr
       | Expr == Expr | Expr /= Expr | Expr < Expr | Expr <= Expr
       | Expr >= Expr | Expr > Expr
       | Expr ++ Expr  --- 文字列の連接
       | Expr * Expr | Expr / Expr 
       | Expr + Expr | Expr - Expr
       | Expr Expr 
       | Const
       | ( Expr )
       | Ident
       | let Decl in Expr
       | letrec Decl in Expr
       | fn Ident -> Expr 
       | if Expr then Expr else Expr
 Decl -> Ident = Expr

 ----------------------------------------------------------------------}

module Err where {

import Text.ParserCombinators.Parsec;
import Text.ParserCombinators.Parsec.Expr;
import Token;

data Value = Num Double | Bool Bool | Str String | Char Char 
           | Fun (Value -> M Value) | Pair Value Value | Unit;

-- Value値を表示するために必要
instance Show Value where {
  showsPrec p (Num d)  = showParen (p>8) (showString "Num " . shows d);
  showsPrec p (Bool b) = showParen (p>8) (showString "Bool " . shows b);
  showsPrec p (Str d)  = showParen (p>8)
                         (showString "Str " . showChar '"' . showString d. showChar '"');
  showsPrec p (Char c) = showParen (p>8) (showChar '\'' . showChar c . showChar '\'');
  showsPrec p (Fun f)  = showParen (p>8) (showString "Fun <function>");
  showsPrec p (Pair v1 v2) = showParen (p>8) (showChar '(' . showsPrec 0 v1 .
                                              showString ", " . showsPrec 0 v2 .
                                              showChar ')');
  showsPrec p Unit     = showString "Unit"
};

showValue (Num d)   = show d;
showValue (Bool b)  = show b;
showValue (Str str) = str;
showValue (Char c)  = [c];
showValue (Fun _)   = "<function>";
showValue (Pair v1 v2) = "("++show v1++", "++show v2++")";
showValue Unit      = "";

-- Exprの抽象構文
{- type Decls = [(String, Expr)] -}
type Decl = (String, Expr);

data Expr = Const Value | Let Decl Expr | Var String  
          | Lambda String Expr | App Expr Expr | If Expr Expr Expr 
          | Letrec Decl Expr
            deriving Show;

parseExpr = buildExpressionParser table parseFactor <?> "expression";

op2 name = \ x y -> App (App (Var name) x) y;

table = [
	 [ Infix (do { try (symbol "*"); return (op2 "*")}) AssocLeft,
	   Infix (do { try (symbol "/"); return (op2 "/")}) AssocLeft,
	   Infix (do { try (symbol "%"); return (op2 "%")}) AssocLeft
	 ],
	 [ Infix (do { try (symbol "+"); return (op2 "+")}) AssocLeft,
	   Infix (do { try (symbol "-"); return (op2 "-")}) AssocLeft
	 ],
	 [ Infix (do { try (symbol "++"); return (op2 "++")}) AssocLeft ],
	 (map (\ op -> Infix (do { try (symbol op); return (op2 op)})
	                     AssocNone)
	  ["==", "/=", "<", "<=", ">=", ">"]),
	 [ Infix (do { try (symbol "&&");
		       return (\ x y -> If x y (Const (Bool False))) })
	   AssocRight
	 ],
	 [ Infix (do { try (symbol "||");
		       return (\ x y -> If x (Const (Bool True)) y) })
	   AssocRight
	 ]
	];


parseFactor = do {
		  es <- many1 parseAtomic;
		  return (foldl1 App es)
		 }
;

parseAtomic = parens parseExpr
              <|>
              (do { t <- naturalOrFloat;
		    return (case t of { Left i -> Const (Num (fromInteger i));
					Right d -> Const (Num d) })
		  })
	      <|>
	      (do {t <- stringLiteral;
		   return (Const (Str t))
		  })
	      <|>
              (do { t <- identifier; return (Var t) })
	      <|>
	      (do { reserved "let";
--		    decls <- parseDecls;
		    decl <- parseDecl;
		    reserved "in";
		    expr  <- parseExpr;
--		    return (Let decls expr)
		    return (Let decl expr)
		  })
	      <|>
	      (do { reserved "letrec";
--		    decls <- parseDecls;
		    decl <- parseDecl;
		    reserved "in";
		    expr  <- parseExpr;
--		    return (Letrec decls expr)
		    return (Letrec decl expr)
		  })
	      <|>
	      (do { (reserved "fn" <|> reservedOp "\\");
		    id <- identifier;
		    reservedOp "->";
		    e <- parseExpr;
		    return (Lambda id e)
		  })
	      <|>
	      (do {
		   reserved "if";
		   e1 <- parseExpr;
		   reserved "then";
		   e2 <- parseExpr;
		   reserved "else";
		   e3 <- parseExpr;
		   return (If e1 e2 e3)
		  })
;

parseDecls = sepBy1 parseDecl semi;
parseDecl = do {
		i <- identifier;
		symbol "=";
		e <- parseExpr;
		return (i, e)
	       }
;

{----------------------------------------------------------------------

 インタプリタ

 ----------------------------------------------------------------------}

type Env = [(String, Value)];

data Err a = Success a | Failure String
             deriving Show;

showErr :: Err Value -> String;
showErr (Success a)   = showValue a;
showErr (Failure str) = "Error: "++str;

unitErr :: a -> Err a;
unitErr a = Success a ;

bindErr :: Err a -> (a -> Err b) -> Err b;
m `bindErr` k = case m of {
                  Success a -> k a;
                  Failure str   -> Failure str
                }; 

type M a = Err a;

unitM :: a -> M a;
unitM a = unitErr a;

bindM :: M a -> (a -> M b) -> M b ;
m `bindM` k = m `bindErr` k;

lookupM :: String -> Env -> M Value;
lookupM x ((n,v):rest)  = if n==x then Success v else lookupM x rest;
lookupM x []            = Failure ("Variable: "++x++" is not found");

failM :: String -> M a;
failM message = Failure message;

--     by Daniel P. Friedman and Amr Sabry
mfixU :: ((a -> M b) -> M (a -> M b)) -> M (a -> M b);
mfixU e = unitM (\ a -> mfixU e `bindM` \ v -> v a) `bindM` \ v ->
          e v;

interp :: Expr -> Env -> M Value;
interp (Const c) e = unitM c;
interp (Var x)   e = lookupM x e;
interp (Let (x, m) n) e = interp m e `bindM` \ v ->
                          interp n ((x,v):e);
interp (App f x) e = interp f e `bindM` \ g ->
                     case g of {
                       Fun h -> interp x e `bindM` \ y ->
                                h y;
                       _     -> failM "Function expected."
                     };    
interp (Letrec (x, m) n) e = mfixU (\ v -> 
                                    interp m ((x, Fun v):e) `bindM` \  v1 ->
                                    case v1 of { 
                                      Fun f -> unitM f; 
                                      _     -> failM "function expected" 
                                    }) `bindM` \ v  ->
                             interp n ((x, Fun v):e);
interp (Lambda x m) e = unitM (Fun (\ v -> interp m ((x,v):e)));
interp (If e1 e2 e3) e = interp e1 e `bindM` \ v ->
                         case v of {
                           Bool b -> if b then interp e2 e
                                          else interp e3 e;
                           _      -> failM "Boolean expected"
                         }; 

binop op =  Fun (\ v ->
              case v of {
                Num c -> unitM (Fun (\ w ->
                           case w of {
                             Num d -> unitM (Num (op c d));
                             _     -> failM "Number expected"
                           }));
                _     -> failM "Number expected"
              });

binop2 op =  Fun (\ v ->
	       case v of {
		 Num c -> unitM (Fun (\ w ->
			    case w of {
			      Num d -> unitM (Bool (op c d));
			      _     -> failM "Number expected"
                            }));
		 _     -> failM "Number expected"
               });

divop = Fun (\ v ->
              case v of {
                Num c -> unitM (Fun (\ w ->
                           case w of {
                             Num 0 -> failM "Division by 0";
                             Num d -> unitM (Num (c/d));
                             _     -> failM "Number expected"
                           }));
                _     -> failM "Number expected"
              });

myPair   = Fun (\ v1 -> unitM (Fun (\ v2 -> unitM (Pair v1 v2))));

myFst = Fun (\ v -> 
  case v of  {
    Pair v1 v2 -> unitM v1;
    _          -> failM "Pair expected"
  });

mySnd = Fun (\ v -> 
  case v of {
    Pair v1 v2 -> unitM v2;
    _          -> failM "Pair expected"
  });

myIsPair = Fun (\ v -> case v of {
                         Pair _ _ -> unitM (Bool True);
                         _        -> unitM (Bool False)
                       });

myIsUnit = Fun (\ v -> case v of {
                       	 Unit -> unitM (Bool True);
                       	 _    -> unitM (Bool False) 
                       });

myToString = Fun (\ v -> unitM (Str (showValue v)));
myStrAppend = Fun (\ v1 -> unitM (Fun (\ v2 ->
              unitM (Str (showValue v1 ++ showValue v2)))));

initEnv = [("+", binop (+)), ("-", binop (-)),
           ("*", binop (*)), ("/", divop),
           ("%", binop (\ x y -> fromInteger (round x `rem` round y))),
           ("not", Fun (\ (Bool b) -> unitM (Bool (not b)))), 
           ("==", binop2 (==)), ("/=", binop2 (/=)),
           (">", binop2 (>)), (">=", binop2 (>=)),
           ("<", binop2 (<)), ("<=", binop2 (<=)),
           ("True", Bool True), ("False", Bool False),
           ("pair", myPair), ("isPair", myIsPair), 
	   ("Unit", Unit), ("isUnit", myIsUnit),
           ("fst", myFst), ("snd", mySnd),
	   ("++", myStrAppend), ("toString", myToString)
	  ];

myParse :: String -> Expr;
myParse str = case
	        (parse (do {whiteSpace; s<- parseExpr; eof; return s }) "" str)
	      of {
                Left err -> Const (Str ("parse error at " ++ show err));
	        Right x  -> x
	      }
;

run :: String -> String;
run str = showErr (interp (myParse str) initEnv);

main :: IO ();
main = interact run;

load :: String -> IO ();
load path = readFile path >>= \ prog ->
   	    putStrLn (run prog);

-- for example, 
-- run "1/0"
-- run "let fact = fn n -> if n==0 then 1 else n*fact(n-1) in fact 9"
}