{----------------------------------------------------------------------

インタプリタ（関数）

* Fun.hs +
* If文の導入
* いくつかのプリミティブ関数を追加


 Expr -> Expr || Expr | Expr && Expr
       | Expr == Expr | Expr /= Expr | Expr < Expr | Expr <= Expr
       | Expr >= Expr | Expr > Expr
       | Expr ++ Expr
       | Expr * Expr | Expr / Expr 
       | Expr + Expr | Expr + Expr
       | Expr Expr 
       | Const
       | ( Expr )
       | Ident
       | let Ident = Expr in Expr
       | fn Ident -> Expr 
       | if Expr then Expr else Expr


 ----------------------------------------------------------------------}

module Fun2 where {

import Text.ParserCombinators.Parsec;
import Text.ParserCombinators.Parsec.Expr;
import Token;

data Value = Num Double | Bool Bool | Str String | Char Char
           | Fun (Value -> M Value) | Pair Value Value | Unit;

-- Value値を表示するために必要
instance Show Value where {
  showsPrec p (Num d)  = showParen (p>8) (showString "Num " . shows d);
  showsPrec p (Bool b) = showParen (p>8) (showString "Bool " . shows b);
  showsPrec p (Str d)  = showParen (p>8)
                         (showString "Str " . showChar '"' . showString d. showChar '"');
  showsPrec p (Char c) = showParen (p>8) (showChar '\'' . showChar c . showChar '\'');
  showsPrec p (Fun f)  = showParen (p>8) (showString "Fun <function>");
  showsPrec p (Pair v1 v2) = showParen (p>8) (showChar '(' . showsPrec 0 v1 .
                                              showString ", " . showsPrec 0 v2 .
                                              showChar ')');
  showsPrec p Unit     = showString "Unit"
};

showValue (Num d)   = show d;
showValue (Bool b)  = show b;
showValue (Str str) = str;
showValue (Char c)  = [c];
showValue (Fun _)   = "<function>";
showValue (Pair v1 v2) = "("++show v1++", "++show v2++")";
showValue Unit      = "";


{-

インタプリタ

* Fun +
* Ifなどの導入

-}

-- Exprの抽象構文
type Decl = (String, Expr);

-- AddとMultの特別扱いをやめる
data Expr = Const Value | Let Decl Expr | Var String  
          | Lambda String Expr | App Expr Expr | If Expr Expr Expr 
            deriving Show ;

parseExpr = buildExpressionParser table parseFactor <?> "expression";

op2 name = \ x y -> App (App (Var name) x) y;

table = [
	 [ Infix (do { try (symbol "*"); return (op2 "*")}) AssocLeft,
	   Infix (do { try (symbol "/"); return (op2 "/")}) AssocLeft,
	   Infix (do { try (symbol "%"); return (op2 "%")}) AssocLeft
	 ],
	 [ Infix (do { try (symbol "+"); return (op2 "+")}) AssocLeft,
	   Infix (do { try (symbol "-"); return (op2 "-")}) AssocLeft
	 ],
	 [ Infix (do { try (symbol "++"); return (op2 "++")}) AssocLeft ],
	 (map (\ op -> Infix (do { try (symbol op); return (op2 op)})
	                     AssocNone)
	  ["==", "/=", "<", "<=", ">=", ">"]),
	 [ Infix (do { try (symbol "&&");
		       return (\ x y -> If x y (Const (Bool False))) })
	   AssocRight
	 ],
	 [ Infix (do { try (symbol "||");
		       return (\ x y -> If x (Const (Bool True)) y) })
	   AssocRight
	 ]
	];


parseFactor = do {
		  es <- many1 parseAtomic;
		  return (foldl1 App es)
		 }
;

parseAtomic = parens parseExpr
              <|>
              (do { t <- naturalOrFloat;
		    return (case t of { Left i -> Const (Num (fromInteger i));
					Right d -> Const (Num d) })
		  })
	      <|>
	      (do {t <- stringLiteral;
		   return (Const (Str t))
		  })
	      <|>
              (do { t <- identifier; return (Var t) })
	      <|>
	      (do { reserved "let";
--		    decls <- parseDecls;
		    decl <- parseDecl;
		    reserved "in";
		    expr  <- parseExpr;
--		    return (Let decls expr)
		    return (Let decl expr)
		  })
	      <|>
	      (do { (reserved "fn" <|> reservedOp "\\");
		    id <- identifier;
		    reservedOp "->";
		    e <- parseExpr;
		    return (Lambda id e)
		  })
	      <|>
	      (do {
		   reserved "if";
		   e1 <- parseExpr;
		   reserved "then";
		   e2 <- parseExpr;
		   reserved "else";
		   e3 <- parseExpr;
		   return (If e1 e2 e3)
		  })
;

parseDecls = sepBy1 parseDecl semi;
parseDecl = do {
		i <- identifier;
		symbol "=";
		e <- parseExpr;
		return (i, e)
	       }
;

{----------------------------------------------------------------------

 インタプリタ

 ----------------------------------------------------------------------}

type M a = a;

unitM :: a -> M a;
unitM a = a;

bindM :: M a -> (a -> M b) -> M b;
m `bindM` k = k m;

type Env = [(String, Value)];

lookup' :: Eq a =>  a -> [(a, b)] -> b;
lookup' x ((n,v):rest) = if n==x then v else lookup' x rest;

{-
 -- Monadic Version
interp :: Expr -> Env -> M Value;
interp (Const c) e = unitM c;
interp (Var x) e  = unitM (lookup' x e);
interp (Let (x, m) n) e = interp m e `bindM` \ v  ->  
                          interp n ((x,v):e);
interp (App f x) e = interp f e `bindM` \ g ->
                     case g of {
		       Fun h -> interp x e `bindM` \ y ->
		                h y;
		       _     -> failM "Function expected" 		 
                     };
interp (Lambda x m) e = unitM (Fun (\ v -> unitM (interp m (newId e x v))));
interp (If e1 e2 e3) e = interp e1 e `bindM` \ v ->
                         case v of {
			   Bool b -> if b then interp e2 e
                                          else interp e3 e;
                           -      -> failM "Boolean expected"
                         }
-}

 -- Non-Monadic Version
interp :: Expr -> Env -> Value;
interp (Const c) e  = c;
interp (Var x) e    = lookup' x e;
interp (Let (x, m) n) e = let { v = interp m e } in
                          interp n ((x,v):e);

interp (App f x) e = case interp f e of { 
                       Fun g -> g (interp x e);
		       _     -> Str "error: Function expected"
                     };
interp (Lambda x m) e = Fun (\ v -> interp m ((x,v):e));

interp (If e1 e2 e3) e = case interp e1 e of {
                           Bool b -> if b then interp e2 e
                                          else interp e3 e;
			   _      -> Str "error: Boolean expected"
                         };

binop op = Fun (\ (Num c) -> unitM (Fun (\ (Num d) -> unitM (Num (op c d)))));
binop2 op = Fun (\ (Num c) -> unitM (Fun (\ (Num d) -> unitM (Bool (op c d)))));

myPair   = Fun (\ v1 -> unitM (Fun (\ v2 -> unitM (Pair v1 v2))));
myFst    = Fun (\ (Pair v1 v2) -> unitM v1);
mySnd    = Fun (\ (Pair v1 v2) -> unitM v2);
myIsPair = Fun (\ v -> case v of {
                         Pair _ _ -> unitM (Bool True);
                         _        -> unitM (Bool False)
                       });
                       
myIsUnit = Fun (\ v -> case v of {
                         Unit -> unitM (Bool True);
                         _    -> unitM (Bool False)
                       });

myToString = Fun (\ v -> unitM (Str (showValue v)));
myStrAppend = Fun (\ v1 -> unitM (Fun (\ v2 ->
              unitM (Str (showValue v1 ++ showValue v2)))));


initEnv = [("+", binop (+)), ("-", binop (-)),
           ("*", binop (*)), ("/", binop (/)),
           ("%", binop (\ x y -> fromInteger (round x `rem` round y))),
           ("not", Fun (\ (Bool b) -> unitM (Bool (not b)))), 
           ("==", binop2 (==)), ("/=", binop2 (/=)),
           (">", binop2 (>)), (">=", binop2 (>=)),
           ("<", binop2 (<)), ("<=", binop2 (<=)),
           ("True", Bool True), ("False", Bool False),
           ("pair", myPair), ("isPair", myIsPair),
	   ("Unit", Unit), ("isUnit", myIsUnit),
           ("fst", myFst), ("snd", mySnd),
	   ("++", myStrAppend), ("toString", myToString)	   
	];

myParse :: String -> Expr;
myParse str = case
	        (parse (do {whiteSpace; s<- parseExpr; eof; return s }) "" str)
	      of {
                Left err -> Const (Str ("parse error at " ++ show err));
	        Right x  -> x
	      }
;

run :: String -> String;
run str = showValue (interp (myParse str) initEnv);

main :: IO ();
main = interact run;

load :: String -> IO ();
load path = readFile path >>= \ prog ->
   	    putStrLn (run prog);

-- for example,
-- run "let sq = fn x -> if x>0 then x*x else 0-x*x in sq 2"
}